10 OPEN15,8,15:POKE53280,6:POKE53281,6:
20 POKE53265,11:PRINT"[147]        ****   DATEI 64[146]   ****"
30 PRINT"        (C)  1985 KLAUS RACZEK"
40 PRINT"  1[146]  [155]DATEI [153]LADEN            *  [158]T  V[156]  I"
50 PRINTSPC(28)"*"
60 PRINT"  2[146]  [155]DATEI [153]SPEICHERN        *  [158]I  E[156]  N"
70 PRINTSPC(28)"*"
80 PRINT"  3[146]  DATEN [152]EINGEBEN         *  [158]G  R"
90 PRINTSPC(28)"*"
100 PRINT"  4[146]  DATEN SUCHEN           *  [158]E  S[156]  2"
110 PRINTSPC(28)"*"
120 PRINT"  5[146]  DATEN AENDERN          *  [158]R  I[156]  0"
130 PRINTSPC(28)"*"
140 PRINT"  6[146]  DATEN LOESCHEN         *  [158]D  O[156]  0"
150 PRINTSPC(28)"*"
160 PRINT"  7[146]  [158]MASKE ERSTELLEN        *  [158]I  N[156]  4"
170 PRINTSPC(28)"*"
180 PRINT"  8[146]  DATEN [152]AUSGEBEN         *  [158]S"
190 PRINTSPC(28)"*"
200 PRINT"  9[146]  [156]PROGRAMM BEENDEN       *  [158]K":POKE53265,27
210 PRINT"[150]     WELCHE NUMMER ";
220 CH=0:INPUTCH$:CH=VAL(CH$):POKE2,CH:IFCH=9THENEND
230 IFCH<1ORCH>8THEN20
240 IFCH=1ORCH=7THENCLR:CH=PEEK(2):OPEN15,8,15
250 ONCHGOSUB270,340,440,510,640,680,790,850
260 GOSUB1030:GOTO20
270 PRINT"[147]NAME DER DATEI";:INPUT"   $ [157][157][157][157]";AA$
280 IFAA$="$"THENGOSUB1040:GOTO270
290 OPEN1,8,2,AA$+",S,R":GOSUB760
300 INPUT#1,FE,N,LE:DIMFE$(FE),S$(FE),DA$(LE,FE)
310 FORX=1TOFE:INPUT#1,FE$(X):NEXT
320 FORI=0TON-1:FORX=1TOFE
330 INPUT#1,DA$(I,X):NEXT:NEXT:CLOSE1:GOSUB760:RETURN
340 IFN=0THENPRINT"[145][145][145][145]":RETURN
350 PRINT"[147]NAME DER DATEI";:INPUT"   $ [157][157][157][157]";AA$
360 IFAA$="$"THENGOSUB1040:GOTO350
370 OPEN1,8,2,AA$+",S,W":GOSUB760:CLOSE1:IFA<>0THEN430
380 OPEN1,8,2,AA$+",S,W"
390 PRINT#1,FE:PRINT#1,N:PRINT#1,LE
400 FORX=1TOFE:PRINT#1,FE$(X)" ":NEXT
410 FORI=0TON-1:FORX=1TOFE
420 PRINT#1,DA$(I,X)" ":NEXT:NEXT
430 CLOSE1:GOSUB760:RETURN
440 PRINT"[147]DATEN EINGEBEN /  EINGABE-ENDE:  RETURN "
450 L=0:FORX=1TOFE:DA$(N,X)=""
460 PRINT""FE$(X)"[146]: ";:INPUTDA$(N,X):IFDA$(N,1)=""THENRETURN
470 IFDA$(N,X)=""THENDA$(N,X)="*"
480 L=L+LEN(DA$(N,X)):NEXT
490 IFL=0THENN=N-1
500 N=N+1:GOSUB1030:GOTO440
510 IFN=0THENPRINT"[145][145][145][145]":RETURN
520 PRINT"[147]SUCHEN:"
530 FORI=1TOFE:PRINT""FE$(I)"[146]: ";:S$(I)="":INPUTS$(I):S(I)=LEN(S$(I)):NEXT
540 EI=0:FORX=0TON-1:FF=0:FORI=1TOFE
550 IFLEFT$(DA$(X,I),S(I))<>S$(I)THENFF=1
560 NEXT:IFFF=0GOTO590
570 NEXT:IFEI=1THENRETURN
580 PRINT"EINTRAG NICHT GEFUNDEN":RETURN
590 IFFL=1THENRETURN
600 PRINT"[147]EINTRAG GEFUNDEN:"
610 FORJ=1TOFE:PRINT""FE$(J)"[146]: "TAB(15)DA$(X,J):NEXT:EI=1
620 GOSUB1030:IFX<NGOTO570
630 RETURN
640 IFN=0THENPRINT"[145][145][145][145]":RETURN
650 PRINT"[147]AENDERN:":PRINT"SUCHEN":FL=1:GOSUB530:FL=0
660 IFX>NTHENRETURN
670 FORI=1TOFE:PRINT""FE$(I)"[146]:":PRINT"  "DA$(X,I):INPUT"[145]";DA$(X,I):NEXT:RETURN
680 IFN=0THENPRINT"[145][145][145][145]":RETURN
690 PRINT"[147]EINTRAG LOESCHEN":PRINT"SUCHEN":GOSUB530
700 PRINT"LOESCHEN (J/N)"
710 GETA$:IFA$=""THEN710
720 IFA$="J"THEN750
730 IFA$<>"N"THEN710
740 RETURN
750 FORI=1TOFE:DA$(X,I)=DA$(N-1,I):DA$(N-1,I)="":NEXT:N=N-1:RETURN
760 INPUT#15,A,A$:IFA=0THENRETURN
770 PRINT""A$:IFA$="FILE EXISTS"THEN980
780 RETURN
790 CLR:OPEN15,8,15:PRINT"[147]EINGABEMASKE ERSTELLEN:"
800 INPUT"WIEVIELE FELDER";FE
810 DIMFE$(FE),S$(FE):PRINT"NAMEN UND MITTLERE LAENGEN DER FELDER   EINGEBEN:"
820 LE=0:FORI=1TOFE:PRINTI;:INPUTFE$(I),X:LE=LE+X:NEXT
830 LE=((FRE(X)+65536)/(LE+FE*3+3)):DIMDA$(LE,FE)
840 PRINT"ES IST PLATZ FUER"INT(LE)"DATENSAETZE.":GOTO260
850 IFN=0THENPRINT"[145][145][145][145]":RETURN
860 PRINT"[147]DATEN AUSGEBEN"
870 PRINT"B[146]ILDSCHIRM ODER D[146]RUCKER ?"
880 GETAG$:IFAG$<>"B"ANDAG$<>"D"ANDAG$<>CHR$(13)THEN880
890 IFAG$=CHR$(13)THENRETURN
900 IFAG$="B"THEN920
910 IFAG$="D"THENPRINT"  DRUCKER EINSCHALTEN ! ":GOSUB970:GOTO940
920 FORX=0TON-1:PRINT"[147]"
930 FORJ=1TOFE:PRINT""FE$(J)"[146]: "TAB(15)DA$(X,J):NEXT:GOSUB970:NEXT:RETURN
940 OPEN4,4,0:FORX=0TON-1
950 FORJ=1TOFE:PRINT#4,SPC(5)DA$(X,J):NEXT:PRINT#4:PRINT#4:NEXT
960 PRINT#4:CLOSE4:RETURN
970 POKE198,0:WAIT198,1:POKE198,0:RETURN
980 PRINT"BESTEHENDE DATEI LOESCHEN ?"
990 GETLO$:IFLO$<>"J"ANDLO$<>"N"THEN990
1000 IFLO$="N"THENRETURN
1010 PRINT#15,"S:"+AA$
1020 A=0:RETURN
1030 PRINT"    TASTE DRUECKEN [146]     ":POKE198,0:WAIT198,1:POKE198,0:RETURN
1040 PRINT"[147]":OPEN1,8,0,"$":POKE781,1:SYS65478:GETDA$,DA$:DE$=CHR$(0)
1050 GETDA$,DA$,DH$,DL$:IFSTTHENSYS65484:CLOSE1:GOTO1090
1060 PRINTASC(DH$+DE$)+256*ASC(DL$+DE$);
1070 GETDA$,DB$:IFDA$THENPRINTDA$DB$;:GOTO1070
1080 PRINTDA$:GOTO1050
1090 GOSUB1030:RETURN